ZPL سے امیج کنورٹر (PNG، JPG)

آن لائن ZPL کو تصویر میں تبدیل کریں: اپنے ZPL کو نیچے پیسٹ کریں اور لیبل کو 152، 203، 300 یا 600 dpi پر PNG یا JPG کے طور پر ڈاؤن لوڈ کریں۔ آزمانے کے لیے مفت، کوئی اکاؤنٹ درکار نہیں۔

^XA
^CI28
^PW812
^LL1216
^LH0,0

^FX === BRAND HEADER ===
^FO32,32^GB748,126,3^FS

^FO52,52^GB76,76,76^FS
^FO65,64^A0N,52,52^FR^FDO^FS

^FO148,53^A0N,48,48^FDOpenZPL^FS
^FO150,108^A0N,19,19^FDYOUR LABELS. PERFECTLY CLEAR.^FS

^FO590,52^GB170,42,42^FS
^FO590,61^A0N,25,25^FB170,1,0,C^FR^FDDEMO LABEL^FS
^FO590,111^A0N,20,20^FB170,1,0,C^FD20 OCT 2026^FS

^FX === SENDER ===
^FO32,183^A0N,18,18^FDSHIP FROM^FS
^FO32,212^A0N,28,28^FDOpenZPL Fulfillment^FS
^FO32,249^A0N,23,23^FD125 Innovation Drive, Austin, TX 78702^FS

^FO32,291^GB748,2,2^FS

^FX === DESTINATION ===
^FO32,315^A0N,18,18^FDSHIP TO^FS
^FO32,350^A0N,52,52^FDALEX MORGAN^FS
^FO32,413^A0N,30,30^FD1234 East 6th Street, Apt 204^FS
^FO32,453^A0N,38,38^FDAUSTIN, TX 78701^FS
^FO32,503^A0N,23,23^FDUNITED STATES^FS

^FO613,325^GB167,183,3^FS
^FO613,345^A0N,19,19^FB167,1,0,C^FDROUTE^FS
^FO613,382^A0N,62,62^FB167,1,0,C^FDAUS^FS
^FO613,460^A0N,26,26^FB167,1,0,C^FDZONE 04^FS

^FX === SERVICE BAND ===
^FO32,550^GB748,65,65^FS
^FO50,568^A0N,34,34^FR^FDEXPRESS DELIVERY^FS
^FO575,572^A0N,26,26^FB185,1,0,R^FR^FDNEXT DAY^FS

^FX === SHIPMENT DETAILS ===
^FO32,643^A0N,17,17^FDORDER NUMBER^FS
^FO32,671^A0N,29,29^FD#10482^FS

^FO292,643^A0N,17,17^FDPACKAGE^FS
^FO292,671^A0N,29,29^FD01 / 03^FS

^FO553,643^A0N,17,17^FDWEIGHT^FS
^FO553,671^A0N,29,29^FD1.25 KG^FS

^FO32,716^GB748,2,2^FS

^FX === CONTENTS TABLE ===
^FO32,738^A0N,18,18^FDITEM / DESCRIPTION^FS
^FO585,738^A0N,18,18^FDQTY^FS
^FO674,738^A0N,18,18^FDLOCATION^FS

^FO32,768^GB748,1,1^FS

^FO32,784^A0N,23,23^FDThermal label rolls - 4 x 6 in^FS
^FO587,784^A0N,23,23^FD02^FS
^FO680,784^A0N,23,23^FDA-12^FS

^FO32,819^GB748,1,1^FS

^FX === TRACKING BARCODE ===
^FO32,844^A0N,17,17^FDTRACKING NUMBER^FS
^BY3,2,108
^FO65,877^BCN,108,N,N,N,A^FD001048200001^FS
^FO32,1000^A0N,25,25^FB500,1,0,C^FD00 10482 00001^FS

^FX === QR CODE ===
^FX ^BQ is shifted down by the current ^BY height, as on a real printer: reset it to the default 10.
^BY3,2,10
^FO602,856^BQN,2,4^FDLA,https://openzpl.com^FS
^FO575,1000^A0N,18,18^FB205,1,0,C^FDTRY OPENZPL^FS

^FX === HANDLING INSTRUCTIONS ===
^FO32,1050^GB748,68,2^FS
^FO50,1064^A0N,18,18^FDDELIVERY INSTRUCTIONS^FS
^FO50,1090^A0N,21,21^FDLeave at reception. Keep dry. Do not bend.^FS

^FX === FOOTER ===
^FO32,1145^GB748,2,2^FS
^FO32,1162^A0N,18,18^FDCreated with OpenZPL^FS
^FO430,1162^A0N,18,18^FB350,1,0,R^FDDEMO ONLY - NOT FOR SHIPPING^FS

^XZ

پیش نظارہ

100%

ZPL کو PNG میں تبدیل کرنے کا طریقہ

اپنا ZPL ایڈیٹر میں چسپاں کریں، یا .zpl فائل کھولیں۔
لیبل کا سائز اور اپنے پرنٹر کی پرنٹ کثافت منتخب کریں (203 dpi سب سے عام ہے)۔
پریویو چیک کریں، پھر PNG ڈاؤن لوڈ کریں۔

اپنے کوڈ سے تبدیل کریں

curl https://api.openzpl.com/v1/printers/8dpmm/labels/4x6/0/ \
  --data-binary @label.zpl > label.png

سوالات

کیا یہ مفت ہے؟

جی ہاں۔ بغیر اکاؤنٹ کے، ایک وقت میں ایک فائل کا پیش منظر دیکھیں اور اس کے تمام لیبلز کے ساتھ ڈاؤن لوڈ کریں، بغیر کسی روزانہ کی حد اور بغیر واٹر مارک۔ ادا شدہ منصوبے فائلز کے بیچ، ای پی آئی اور مدد شامل کرتے ہیں۔

کیا میرا ZPL محفوظ ہے؟

ادائیگی والے منصوبوں پر اور API کلیدوں کے ساتھ، کبھی نہیں: لیبل رینڈر کیا جاتا ہے اور واپس کیا جاتا ہے۔ بغیر کسی کے، ہم ناکام رنڈرز کے ZPL اور دوسروں کے چھوٹے نمونے کو 24 گھنٹے تک محفوظ رکھ سکتے ہیں تاکہ رینڈرنگ کی غلطیاں تلاش کریں، پھر یہ حذف کر دیا جاتا ہے۔ ایڈیٹر آپ کے آخری لیبل کو صرف اس براؤزر میں یاد رکھتا ہے۔

گری اسکیل یا 1-bit؟

گری اسکیل اسکرینز کے لیے ہموار کنارے رکھتا ہے۔ بِیٹونل (1-bit) وہی ہے جو تھرمل پرنٹر پر پرنٹ ہوتا ہے اور چھوٹے فائلز فراہم کرتا ہے؛ اسے مکمل ایڈیٹر میں منتخب کریں۔